@echo off
chcp 65001 >nul
set binpath=%~dp0
if not exist "%binpath%\ffmpeg.exe" echo ffmpeg not found. exiting... & echo. & pause & exit 1
cmd.exe /c tasklist /FI "IMAGENAME eq ProcessTamerTray.exe" | find /I /N "ProcessTamerTray.exe" ||start "" "%binpath%ProcessTamerPortable64\ProcessTamerTray.exe"
:do
if [%1]==[] goto noarg
%~d1
cd "%~dp1"
if not exist "ok\" mkdir ok
if not exist "orig\" mkdir orig
title ffmpeg: %~n1
echo vid: %1
echo start libsvtav1 %date% %time%
"%binpath%\ffmpeg.exe" -hide_banner -hwaccel_output_format cuda -i %1 -c:v libsvtav1 -preset 6 -tune animation -crf 30 -c:s copy -map 0 -map -v -map V "ok\%~n1 - AV1 [AlbiRip].mkv"
if %ERRORLEVEL% NEQ 0 (
  echo ######################################
  echo ## %~n1 ERREUR !!!  ##
  echo ######################################
  del "ok\%~n1 - AV1 [AlbiRip].mkv"
) else (
  echo stop: %date% %time%
  move "%~nx1" "orig\"
  echo _______________________________________
  echo −− %~n1 OK −−
  echo ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
)
"%binpath%\sounder.exe" /vol 25 "%binpath%\Infobulle.wav"
shift /1
if [%1] NEQ [] goto do
::alert, use a wav file with CLI player from https://elifulkerson.com/projects/commandline-wav-player.php
"%binpath%\sounder.exe" "%binpath%\alert.wav"
taskkill /im ProcessTamerTray.exe
::timeout 300
:: veille
::rundll32.exe powrprof.dll,SetSuspendState 1,0,1 
:: veille prolongée
::rundll32.exe powrprof.dll,SetSuspendState 0,1,0
pause
exit 0

:: presets: 1_ultrafast,  6_medium,  9_veryslow
:: crf: exponential, 0 is lossless, 23 is the default, and 51 is worst quality possible

:noarg
echo Usage: %~nx0 "video to convert.flv"
echo.
pause
exit 0